configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl old autoconf
   4 AC_INIT(src/)
   5
   6 dnl new autoconf
   7 dnl AC_INIT
   8 dnl AC_CONFIG_SRCDIR([src/])
   9
  10 # ------------------- option parsing -------------------------------
  11
  12 DEBUG=
  13 CHECKMEM=
  14 PROFILING=
  15 ENABLE_WARNINGS=
  16 OPTIMIZE=
  17 DISABLE_LAME=
  18
  19 AC_ARG_ENABLE(checkmem,
  20 [  --enable-checkmem       turn on ccmalloc debugging], CHECKMEM=true)
  21 AC_ARG_ENABLE(debug,
  22 [  --enable-debug          turn on debugging], DEBUG=true)
  23 AC_ARG_ENABLE(profiling,
  24 [  --enable-profiling      turn on profiling], PROFILING=true)
  25 AC_ARG_ENABLE(warnings,
  26 [  --enable-warnings       turn on compiler warnings], ENABLE_WARNINGS=true)
  27 AC_ARG_ENABLE(optimizations,
  28 [  --enable-optimizations  turn on compiler optimizations (recommended for avi2swf)], OPTIMIZE=true)
  29 AC_ARG_ENABLE(lame,
  30 [  --disable-lame          don't compile any L.A.M.E. mp3 encoding code in],
  31
  32 if test "x$enable_lame" = "xno";then
  33     DISABLE_LAME=yes
  34 fi,DISABLE_LAME=)
  35
  36 PACKAGE=swftools
  37 VERSION=2010-02-06-1900
  38
  39 # ------------------------------------------------------------------
  40
  41 if test "x${srcdir}" != "x."; then
  42     echo "--srcdir is not supported"
  43     exit 1
  44 fi
  45
  46 WARNINGS="-Wimplicit -Wreturn-type -Wno-write-strings -Wformat"
  47 if test "x$ENABLE_WARNINGS" '!=' "x";then
  48     WARNINGS="-Wall -Wno-unused -Wno-format -Wno-redundant-decls -Wno-write-strings -D_FORTIFY_SOURCE=2 "
  49 fi
  50
  51 if test "x$CHECKMEM" '!=' "x";then
  52     DEBUG=yes
  53 fi
  54 if test "x$PROFILING" '!=' "x";then
  55     DEBUG=yes
  56 fi
  57 if test "x$DEBUG" '!=' "x";then
  58     if test "x$PROFILING" = "x";then
  59         CFLAGS="$WARNINGS -O2 -g $CFLAGS"
  60         CXXFLAGS="$WARNINGS -O2 -g $CXXFLAGS"
  61         LDFLAGS="-g $LDFLAGS"
  62     else
  63         CFLAGS="$WARNINGS -O2 -g -pg $CFLAGS"
  64         CXXFLAGS="$WARNINGS -O2 -g -pg $CXXFLAGS"
  65         LDFLAGS="-g -pg $LDFLAGS"
  66     fi
  67 else if test "x$OPTIMIZE" '!=' "x"; then
  68     CFLAGS="$WARNINGS -O3 -fomit-frame-pointer -Winline $CFLAGS"
  69     CXXFLAGS="$WARNINGS -O3 -fomit-frame-pointer -Winline $CXXFLAGS"
  70 else
  71     CFLAGS="$WARNINGS -O -fomit-frame-pointer $CFLAGS"
  72     CXXFLAGS="$WARNINGS -O -fomit-frame-pointer $CXXFLAGS"
  73 fi
  74 fi
  75
  76 CFLAGS="-fPIC $CFLAGS"
  77 CXXFLAGS="-fPIC $CFLAGS"
  78
  79 #OLDGCC=1
  80 #if test "x$OLDGCC" '!=' "x";then
  81 #     #CFLAGS="$CFLAGS --std=c89 -ansi -pendantic"
  82 #     #CXXFLAGS="$CXXFLAGS --std=c89 -ansi -pendantic"
  83 #     CFLAGS="$CFLAGS -ansi -pendantic"
  84 #     CXXFLAGS="$CXXFLAGS -ansi -pendantic"
  85 #fi
  86
  87 export PACKAGE VERSION CFLAGS CXXFLAGS
  88
  89 dnl Checks for programs.
  90
  91 AC_CANONICAL_HOST
  92
  93 SHARED="-shared"
  94 MACOSX=
  95 case $host_os in
  96     *darwin* )
  97         MACOSX=yes
  98         CFLAGS="$CFLAGS"
  99         CXXFLAGS="$CXXFLAGS -fno-rtti"
 100         SHARED="-bundle"
 101         if test -d /opt/local/include && test -d /opt/local/lib; then
 102             CPPFLAGS="${CPPFLAGS} -I/opt/local/include"
 103             LDFLAGS="${LDFLAGS} -L/opt/local/lib"
 104         fi
 105         # Use fink packages if available.
 106         #if test -d /sw/include && test -d /sw/lib; then
 107         #    CPPFLAGS="${CPPFLAGS} -I/sw/include"
 108         #    LDFLAGS="${LDFLAGS} -L/sw/lib"
 109         #fi
 110         ;;
 111 esac
 112
 113 AC_SUBST(SHARED)
 114
 115 dnl Checks for programs.
 116  AC_PROG_CC
 117  AC_PROG_CXX
 118
 119
 120 RFX_CHECK_OLDGCC
 121
 122 if test "x$GCC_IS_OK" '=' "x";then
 123     echo "***************************************************"
 124     echo "* Your gcc is too old to compile this!"
 125     echo "* "
 126     echo "* The last version compileable by this compiler is "
 127     echo "* swftools 0.7.0, which you can download from "
 128     echo "* http://www.swftools.org/swftools-0.7.0.tar.gz "
 129     echo "* ."
 130     echo "* Newer versions require at least gcc 3.0.0 "
 131     echo "***************************************************"
 132     exit 1
 133 fi
 134
 135 if test "x$CHECKMEM" '!=' "x";then
 136     CC="ccmalloc $CC"
 137     CXX="ccmalloc $CXX"
 138     #echo running again
 139     #unset ac_cv_prog_CC
 140     #unset ac_cv_prog_CXX
 141     #AC_PROG_CC
 142     #AC_PROG_CXX
 143 fi
 144  AC_PROG_CPP
 145
 146  AC_PROG_RANLIB
 147  AC_PROG_MAKE_SET
 148  AC_PROG_INSTALL
 149  AC_PROG_LN_S
 150  AC_CHECK_PROGS(UNCOMPRESS, gzip uncompress compress, )
 151
 152 dnl PKG_PROG_PKG_CONFIG
 153
 154 dnl Checks for system services
 155 OBJEXT="o"
 156 AREXT=".a"
 157 CXXLIBS="-lstdc++"
 158
 159 AC_EXEEXT
 160
 161 if test "x$EXEEXT" = "x.exe";then
 162     OBJEXT="obj"
 163     AREXT=".lib"
 164     CXXLIBS=""
 165 fi
 166 AC_SUBST(OBJEXT)
 167 AC_SUBST(AREXT)
 168
 169 RFX_CHECK_MING
 170
 171 SLEXT="so"
 172 if test "x${MINGW}" != "xyes"; then
 173     # no mingW
 174     AC_DEFINE([O_BINARY], [0], [Not defined on mingw])
 175 else
 176     # mingW
 177     SLEXT="dll"
 178     CXXLIBS=""
 179 fi
 180 export SLEXT
 181 AC_SUBST(SLEXT)
 182 AC_SUBST(CXXLIBS)
 183
 184 # The following tries to make use of includes and libraries in
 185 # /usr/local, too. Notice: A -I/usr/local/include might break
 186 # things (MingW, cross-compiling etc.) in the same way as -I/usr/include,
 187 # especially on systems which link /usr/local to /usr, so it has yet
 188 # to be seen how useful this is.
 189 if test -d /usr/local/lib; then
 190     LDFLAGS="$LDFLAGS -L/usr/local/lib"
 191 fi
 192 if test -d /usr/local/include; then
 193 # Leave that alone. It's causing trouble e.g. with gcc 3.2 on gentoo.
 194 #   CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 195     echo > /dev/null
 196 fi
 197 if test "$prefix" != "NONE" -a "$prefix" != "/usr/local" -a "$prefix" != "/usr/local/"; then
 198     # if the user has a special prefix (like /opt), there might also be $prefix/lib
 199     # and $prefix/include, which should be included in our search paths for libraries
 200     # and includes.
 201     LDFLAGS="$LDFLAGS -L${libdir}"
 202     CPPFLAGS="$CPPFLAGS -I${includedir}"
 203     # TODO- test whether gcc still works after this
 204 fi
 205
 206 #Mac OS:
 207 #LDFLAGS "-L/sw/lib" ; CPPFLAGS "-I/sw/include -I/sw/include/lame"
 208
 209
 210 # this must be done after (I believe) AC_PROG_MAKE_SET
 211 if test "x$DEBUG" '!=' "x" -o "x$STRIP" = "x";then
 212     if test "$MACOSX";then
 213         STRIP=dsymutil
 214     else
 215         STRIP="@echo debug enabled, not stripping "
 216     fi
 217     export STRIP
 218     AC_SUBST(STRIP)
 219 fi
 220
 221 dnl Checks for libraries.
 222  AC_CHECK_LIB(m, sin,,
 223  echo "Error: Math library not found.";
 224  exit;
 225  )
 226  AC_CHECK_LIB(z, deflate,, ZLIBMISSING=true)
 227
 228 if test "x$ZLIBMISSING" = "xtrue";then
 229     echo
 230     echo "ERROR:"
 231     echo "You need zlib to compile swftools"
 232     echo
 233     exit
 234 fi
 235
 236 AC_CHECK_LIB(pdf, PDF_open_file,, PDFLIBMISSING=true)
 237 AC_CHECK_LIB(jpeg, jpeg_write_raw_data,, JPEGLIBMISSING=true)
 238 AC_CHECK_LIB(ungif, DGifOpen,, UNGIFMISSING=true)
 239 if test "$UNGIFMISSING";then
 240     UNGIFMISSING=
 241     AC_CHECK_LIB(gif, DGifOpen,, UNGIFMISSING=true)
 242 fi
 243 AC_CHECK_LIB(zzip, zzip_file_open,, ZZIPMISSING=true)
 244
 245 RFX_CHECK_BYTEORDER
 246 AC_SUBST(WORDS_BIGENDIAN)
 247 RFX_CHECK_SYSTEM_BACKTICKS
 248 AC_SUBST(SYSTEM_BACKTICKS)
 249
 250 AC_ARG_PROGRAM
 251
 252 dnl Checks for header files.
 253  AC_CONFIG_HEADER(config.h)
 254  AC_HEADER_DIRENT
 255  AC_HEADER_STDC
 256
 257  AC_CHECK_HEADERS(zlib.h gif_lib.h io.h wchar.h jpeglib.h assert.h signal.h pthread.h sys/stat.h sys/mman.h sys/types.h dirent.h sys/bsdtypes.h sys/ndir.h sys/dir.h ndir.h time.h sys/time.h sys/resource.h pdflib.h zzip/lib.h)
 258
 259 AC_DEFINE_UNQUOTED([PACKAGE], ["$PACKAGE"], [Name of package])
 260 AC_DEFINE_UNQUOTED([VERSION], ["$VERSION"], [Version number of package])
 261 AC_SUBST(PACKAGE)
 262 AC_SUBST(VERSION)
 263
 264 AC_SUBST(HAVE_UNISTD_H)
 265 AC_SUBST(EXEEXT)
 266
 267 dnl Checks for typedefs, structures, and compiler characteristics.
 268  AC_C_CONST
 269  AC_C_INLINE
 270  AC_TYPE_OFF_T
 271  AC_TYPE_SIZE_T
 272  AC_STRUCT_TM
 273  AC_CHECK_TYPE(boolean,int) #needed for jpeglib
 274  AC_CHECK_FUNCS(popen wcschr wcsdup mkstemp stat mmap lrand48 rand srand48 srand bcopy bzero time getrusage mallinfo)
 275
 276 AC_CHECK_SIZEOF([signed char])
 277 AC_CHECK_SIZEOF([signed short])
 278 AC_CHECK_SIZEOF([signed])
 279 AC_CHECK_SIZEOF([signed long long])
 280 AC_CHECK_SIZEOF([void*])
 281
 282 RFX_CHECK_FREETYPE
 283
 284 RFX_CHECK_FONTCONFIG
 285
 286 RFX_CHECK_FFTW
 287
 288 # RFX_CHECK_OPENGL
 289 # if test "$HAVE_OPENGL";then
 290 #     DEVICE_OPENGL='devices/opengl.$(O)'
 291 #     AC_SUBST(DEVICE_OPENGL)
 292 # fi
 293 AC_SUBST(DEVICE_OPENGL)
 294
 295 lame_in_source=
 296 lame_makefile=
 297 if test "x${DISABLE_LAME}" = "xtrue"; then
 298     echo "*" Disabling lame support...
 299 else
 300     # old lame code at lib/lame
 301     if test -f lib/lame/Makefile.in; then
 302         lame_in_source='$(lame_objects)'
 303         lame_makefile="lib/lame/Makefile"
 304         CPPFLAGS="$CPPFLAGS -Ilame -Ilib/lame"
 305         AC_DEFINE([HAVE_LAME], [1], [have/use internal l.a.m.e. mp3 library])
 306     else
 307         if test -d /usr/include/lame; then
 308             CPPFLAGS="$CPPFLAGS -I /usr/include/lame"
 309         else
 310             if test -d /usr/local/include/lame; then
 311                 CPPFLAGS="$CPPFLAGS -I /usr/local/include/lame"
 312             fi
 313         fi
 314         AC_CHECK_LIB(mp3lame, lame_init,, NO_LIBMP3LAME=1)
 315         HASLAMEHEADER=
 316         AC_CHECK_HEADERS(lame.h,HASLAMEHEADER=1)
 317         if test "x$NO_LIBMP3LAME" "!=" "x1" -a "x$HASLAMEHEADER" '!=' "x";then
 318             AC_DEFINE([HAVE_LAME], [1])
 319         fi
 320     fi
 321 fi
 322 AC_SUBST(lame_in_source)
 323
 324 splash_in_source='$(splash_objects)'
 325 xpdf_in_source='$(xpdf_objects)'
 326
 327 dnl if test "x$USE_POPPLER" = "xtrue"; then
 328 dnl     xpdf_in_source=
 329 dnl     splash_in_source=
 330 dnl     AC_DEFINE([HAVE_POPPLER],[1],[use poppler])
 331 dnl     PKG_CHECK_MODULES([POPPLER],[poppler poppler-splash],,[poppler_pkgconfig=no])
 332 dnl     if test "x$poppler_pkgconfig" = "xno"; then
 333 dnl         AC_LANG_PUSH([C++])
 334 dnl         AC_CHECK_HEADERS([OutputDev.h],[
 335 dnl            AC_CHECK_LIB([poppler],[main],,[])
 336 dnl         ],[AC_MSG_ERROR([No poppler library found. This library is required.])])
 337 dnl         AC_LANG_POP
 338 dnl     else
 339 dnl     CPPFLAGS="$CPPFLAGS $POPPLER_CFLAGS"
 340 dnl         AC_DEFINE([HAVE_POPPLER], [1])
 341 dnl         LIBS="$LIBS $POPPLER_LIBS"
 342 dnl     fi
 343 dnl fi
 344
 345 AC_SUBST([xpdf_in_source])
 346 AC_SUBST([splash_in_source])
 347
 348 # ------------------------------------------------------------------
 349
 350 RFX_CHECK_LOWERCASE_UPPERCASE
 351 RFX_CHECK_AVI2SWF
 352 if test "x${AVIFILE}" = "xtrue"; then
 353     VIDEO_LIBS="$VIDEO_LIBS $AVIFILE_LIBS"
 354     VIDEO_CFLAGS="$VIDEO_CFLAGS $AVIFILE_CFLAGS"
 355     AC_DEFINE([HAVE_AVIFILE], [1], [Define if avifile is present])
 356 fi
 357
 358 if test "x${WIN32}" != "x"; then
 359     #AC_CHECK_LIB(avifil32, AVIFileInit,AVIFIL32=true)
 360     #if test "x${AVIFIL32}" != "x"; then
 361     #  VIDEO_LIBS="$VIDEO_LIBS -lavifil32"
 362     #fi
 363     VIDEO_LIBS="$VIDEO_LIBS -lavifil32"
 364     AVIFIL32=true
 365 fi
 366
 367 AC_SUBST(VIDEO_LIBS)
 368 AC_SUBST(VIDEO_CFLAGS)
 369 # ------------------------------------------------------------------
 370
 371 if test "x${UNCOMPRESS}" = "xgzip"; then
 372     AC_DEFINE([USE_GZIP], [1], [Define if gzip is present])
 373 fi
 374 AC_SUBST(USE_GZIP)
 375
 376 # ------------------------------------------------------------------
 377
 378 RFX_CHECK_PYTHON
 379
 380 if test "x$PYTHON_OK" '!=' "xyes";then
 381     echo all install uninstall clean: > lib/python/Makefile
 382     # fail silently- the most users won't have any need for the
 383     # python interface anyway
 384 else
 385     pythongfx="lib/python/Makefile"
 386 fi
 387
 388 # ------------------------------------------------------------------
 389
 390 RFX_CHECK_RUBY
 391
 392 if test "x$RUBY_OK" '!=' "xyes";then
 393     echo all install uninstall clean: > lib/ruby/Makefile
 394     # fail silently- the most users won't have any need for the
 395     # ruby interface anyway
 396 else
 397     rubygfx="lib/python/Makefile"
 398 fi
 399
 400 # ------------------------------------------------------------------
 401
 402 AC_MSG_CHECKING([for missing libraries])
 403
 404 if test "x$ZLIBMISSING" = "xtrue";then
 405     MISSINGLIBS="${MISSINGLIBS} zlib"
 406     DISABLEPNG2SWF=true
 407     PARTIAL=true
 408 fi
 409 if test "x$JPEGLIBMISSING" = "xtrue";then
 410     MISSINGLIBS="${MISSINGLIBS} jpeglib"
 411     DISABLEPDF2SWF=true
 412     DISABLEJPEG2SWF=true
 413     PARTIAL=true
 414 fi
 415 if test "x$PDFLIBMISSING" = "xtrue";then
 416     DISABLEPDF2PDF=true;
 417 fi
 418 #if test "x$T1LIBMISSING" = "xtrue";then
 419 #    MISSINGLIBS="${MISSINGLIBS} t1lib"
 420 #fi
 421 if test "x$UNGIFMISSING" = "xtrue";then
 422     DISABLEGIF2SWF=true
 423     MISSINGLIBS="${MISSINGLIBS} ungif"
 424     PARTIAL=true
 425 fi
 426
 427 if test "x${ac_cv_header_pdflib_h}" '!=' "xyes";then
 428     DISABLEPDF2PDF=true;
 429 fi
 430 if test "x${ac_cv_header_jpeglib_h}" '!=' "xyes"; then
 431     DISABLEPDF2SWF=true;
 432     DISABLEJPEG2SWF=true;
 433     MISSINGLIBS="${MISSINGLIBS} jpeglib.h"
 434     PARTIAL=true
 435 fi
 436 if test "x$HAVE_FREETYPE" '!=' "x1"; then
 437     DISABLEPDF2SWF=true;
 438     MISSINGLIBS="${MISSINGLIBS} freetype"
 439     PARTIAL=true
 440 fi
 441 #if test "x${ac_cv_header_t1lib_h}" '!=' "xyes"; then
 442 #    MISSINGLIBS="${MISSINGLIBS} t1lib.h"
 443 #fi
 444 if test "x${ac_cv_header_gif_lib_h}" '!=' "xyes"; then
 445     DISABLEGIF2SWF=true
 446     MISSINGLIBS="${MISSINGLIBS} gif_lib.h"
 447     PARTIAL=true
 448 fi
 449 if test "x${ac_cv_header_zlib_h}" '!=' "xyes"; then
 450     DISABLEPNG2SWF=true;
 451     MISSINGLIBS="${MISSINGLIBS} zlib.h"
 452     PARTIAL=true
 453 fi
 454 #if test "x${AVIFILE}" '!=' "xtrue" -a "x${AVIFIL32}" '!=' "xtrue"; then
 455 #    MISSINGLIBS="${MISSINGLIBS} avifile"
 456 #fi
 457
 458 AC_MSG_RESULT(${MISSINGLIBS})
 459
 460 # ------------------------------------------------------------------
 461
 462 if test "x${MISSINGLIBS}" '!=' "x"; then
 463   echo "***************************************************"
 464   echo "* The following headers/libraries are missing: " ${MISSINGLIBS}
 465 fi
 466
 467 avi2swf="avi2swf/Makefile"
 468 if test "x${AVIFILE}" '!=' "xtrue" -a "x${AVIFIL32}" '!=' "xtrue"; then
 469  #don't whine, avi2swf is outdated anyway
 470  #echo "* Disabling avi2swf tool..."
 471  echo all install uninstall clean: > avi2swf/Makefile
 472  avi2swf=
 473 fi
 474
 475 pdf2swf_makefile="lib/pdf/Makefile"
 476 PDF2SWF='pdf2swf$(E)'
 477 LIBPDF='libpdf$(A)'
 478
 479 if test "x${DISABLEPDF2SWF}" = "xtrue"; then
 480   echo "* Disabling pdf2swf tool..."
 481   rm -f lib/pdf/Makefile
 482   echo all install uninstall clean libpdf libgfxpdf: > lib/pdf/Makefile
 483   pdf2swf_makefile=""
 484   PDF2SWF=
 485   LIBPDF=
 486 fi
 487 AC_SUBST(PDF2SWF)
 488 AC_SUBST(LIBPDF)
 489
 490 PDF2PDF='pdf2pdf$(E)'
 491 DEVICE_PDF='devices/pdf.$(O)'
 492 if test "x${DISABLEPDF2PDF}" = "xtrue"; then
 493   #echo "* Disabling pdf2pdf tool..."
 494   PDF2PDF=
 495   DEVICE_PDF=
 496 fi
 497 AC_SUBST(DEVICE_PDF)
 498 AC_SUBST(PDF2PDF)
 499
 500 if test "x${ZLIBMISSING}" = "xtrue"; then
 501   echo
 502   echo "* Warning! Without zlib, you will not be able to read"
 503   echo "* or write compressed Flash MX files!"
 504 fi
 505
 506 JPEG2SWF='jpeg2swf$(E)'
 507 if test "x${DISABLEJPEG2SWF}" = "xtrue"; then
 508   echo "* Disabling jpeg2swf tool..."
 509   JPEG2SWF=
 510 fi
 511 export JPEG2SWF
 512 AC_SUBST(JPEG2SWF)
 513
 514 GIF2SWF='gif2swf$(E)'
 515 if test "x${DISABLEGIF2SWF}" = "xtrue"; then
 516   echo "* Disabling gif2swf tool..."
 517   GIF2SWF=
 518 fi
 519 export GIF2SWF
 520 AC_SUBST(GIF2SWF)
 521
 522 PNG2SWF='png2swf$(E)'
 523 if test "x${DISABLEPNG2SWF}" = "xtrue"; then
 524   echo "* Disabling png2swf tool..."
 525   PNG2SWF=
 526 fi
 527 export PNG2SWF
 528 AC_SUBST(PNG2SWF)
 529
 530 if test "x${MISSINGLIBS}" '!=' "x"; then
 531   if test "x${PARTIAL}" '=' "x"; then
 532     echo "* (never mind)"
 533   fi
 534   echo "***************************************************"
 535 fi
 536
 537 # ------------------------------------------------------------------
 538
 539 AH_TOP([
 540 #ifndef __config_h__
 541 #define __config_h__
 542 ])
 543
 544 AH_BOTTOM([
 545 #ifdef HAVE_ZLIB_H
 546 #ifdef HAVE_LIBZ
 547 #define HAVE_ZLIB
 548 #endif
 549 #endif
 550
 551 #ifdef HAVE_JPEGLIB_H
 552 #ifdef HAVE_LIBJPEG
 553 #define HAVE_JPEGLIB
 554 #endif
 555 #endif
 556
 557 #ifdef HAVE_FT2BUILD_H
 558 #define HAVE_FREETYPE_H 1
 559 #endif
 560
 561 #ifdef HAVE_GL_GL_H
 562 #ifdef HAVE_GL_GLUT_H
 563 #ifdef HAVE_OPENGL
 564 #define USE_OPENGL
 565 #endif
 566 #endif
 567 #endif
 568
 569 #ifdef HAVE_POPPLER
 570 #define GString GooString
 571 #define GHash GooHash
 572 #endif
 573
 574 #ifdef HAVE_ZZIP_LIB_H
 575 #ifdef HAVE_LIBZZIP
 576 #define HAVE_ZZIP 1
 577 #endif
 578 #endif
 579
 580
 581 #endif // __config_h__
 582 ])
 583
 584 if test -f "release.in"; then release_in="./release"; fi
 585 if test -f "Makefile.new.in"; then mk_in="./Makefile.new"; fi
 586 FILES="$release_in $mk_in Makefile.common ${avi2swf} Makefile lib/Makefile lib/action/Makefile src/Makefile ${pdf2swf_makefile} swfs/Makefile ${pythongfx} ${lame_makefile} lib/readers/Makefile"
 587 AC_OUTPUT(${FILES})
 588
 589 dnl new autoconf
 590 dnl AC_CONFIG_FILES([${FILES}])
 591 dnl AC_OUTPUT
 592
 593 #
 594 # On development trees, create snapshots of config.status
 595 #
 596 if test -f snapshot -a "x$CHECKMEM" = "x" -a "x$PROFILING" = "x";then
 597     if test "x${MINGW}" = "xyes"; then
 598         echo cp config.status config.status.win32
 599         cp config.status config.status.win32
 600     else
 601         if test "x$DEBUG" '=' "x" -a "x$OPTIMIZE"  '=' "x";then
 602             echo cp config.status config.status.linux
 603             cp config.status config.status.linux
 604         fi
 605         if test "x$DEBUG" '!=' "x" -a "x$OPTIMIZE"  '=' "x";then
 606             echo cp config.status config.status.debug
 607             cp config.status config.status.debug
 608         fi
 609         if test "x$DEBUG"    = "x" -a "x$OPTIMIZE" '!=' "x"; then
 610             echo cp config.status config.status.optimize
 611             cp config.status config.status.optimize
 612         fi
 613     fi
 614 fi