lib/as3/tokenizer.lex

   1 /* tokenizer.lex
   2
   3    Routines for compiling Flash2 AVM2 ABC Actionscript
   4
   5    Extension module for the rfxswf library.
   6    Part of the swftools package.
   7
   8    Copyright (c) 2008 Matthias Kramm <kramm@quiss.org>
   9
  10    This program is free software; you can redistribute it and/or modify
  11    it under the terms of the GNU General Public License as published by
  12    the Free Software Foundation; either version 2 of the License, or
  13    (at your option) any later version.
  14
  15    This program is distributed in the hope that it will be useful,
  16    but WITHOUT ANY WARRANTY; without even the implied warranty of
  17    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18    GNU General Public License for more details.
  19
  20    You should have received a copy of the GNU General Public License
  21    along with this program; if not, write to the Free Software
  22    Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA */
  23 %{
  24
  25
  26 #include <string.h>
  27 #include <stdlib.h>
  28 #include <stdio.h>
  29 #include <stdarg.h>
  30 #include "../utf8.h"
  31 #include "common.h"
  32 #include "tokenizer.h"
  33 #include "files.h"
  34
  35 unsigned int as3_tokencount = 0;
  36
  37 static void dbg(const char*format, ...)
  38 {
  39     char buf[1024];
  40     int l;
  41     va_list arglist;
  42     if(as3_verbosity<3)
  43         return;
  44     va_start(arglist, format);
  45     vsnprintf(buf, sizeof(buf)-1, format, arglist);
  46     va_end(arglist);
  47     l = strlen(buf);
  48     while(l && buf[l-1]=='\n') {
  49         buf[l-1] = 0;
  50         l--;
  51     }
  52     printf("(tokenizer) ");
  53     printf("%s\n", buf);
  54     fflush(stdout);
  55 }
  56
  57 #ifndef YY_CURRENT_BUFFER
  58 #define YY_CURRENT_BUFFER yy_current_buffer
  59 #endif
  60
  61 static void*as3_buffer=0;
  62 static int as3_buffer_pos=0;
  63 static int as3_buffer_len=0;
  64 void as3_file_input(FILE*fi)
  65 {
  66     as3_in = fi;
  67     as3_buffer = 0;
  68 }
  69 void as3_buffer_input(void*buffer, int len)
  70 {
  71     if(!buffer)
  72         syntaxerror("trying to parse zero bytearray");
  73     as3_buffer = buffer;
  74     as3_buffer_len = len;
  75     as3_buffer_pos = 0;
  76     as3_in = 0;
  77 }
  78
  79 //#undef BEGIN
  80 //#define BEGIN(x) {(yy_start) = 1 + 2 *x;dbg("entering state %d", x);}
  81
  82 #define YY_INPUT(buf,result,max_size) { \
  83   if(!as3_buffer) { \
  84       errno=0; \
  85       while((result = fread(buf, 1, max_size, as3_in))==0 && ferror(as3_in)) \
  86       { if(errno != EINTR) {YY_FATAL_ERROR("input in flex scanner failed"); break;} \
  87         errno=0; clearerr(as3_in); \
  88       } \
  89   } else { \
  90       int to_read = max_size; \
  91       if(to_read + as3_buffer_pos > as3_buffer_len) \
  92           to_read = as3_buffer_len - as3_buffer_pos; \
  93       memcpy(buf, as3_buffer+as3_buffer_pos, to_read); \
  94       as3_buffer_pos += to_read; \
  95       result=to_read; \
  96   } \
  97 }
  98
  99 void handleInclude(char*text, int len, char quotes)
 100 {
 101     char*filename = 0;
 102     if(quotes) {
 103         char*p1 = strchr(text, '"');
 104         char*p2 = strrchr(text, '"');
 105         if(!p1 || !p2 || p1==p2) {
 106             syntaxerror("Invalid include in line %d\n", current_line);
 107         }
 108         *p2 = 0;
 109         filename = strdup(p1+1);
 110     } else {
 111         int i1=0,i2=len;
 112         // find start
 113         while(!strchr(" \n\r\t", text[i1])) i1++;
 114         // strip
 115         while(strchr(" \n\r\t", text[i1])) i1++;
 116         while(strchr(" \n\r\t", text[i2-1])) i2--;
 117         if(i2!=len) text[i2]=0;
 118         filename = strdup(&text[i1]);
 119     }
 120
 121     char*fullfilename = find_file(filename, 1);
 122     enter_file2(filename, fullfilename, YY_CURRENT_BUFFER);
 123     yyin = fopen(fullfilename, "rb");
 124     if (!yyin) {
 125         syntaxerror("Couldn't open include file \"%s\"\n", fullfilename);
 126     }
 127
 128     yy_switch_to_buffer(yy_create_buffer( yyin, YY_BUF_SIZE ) );
 129     //BEGIN(DEFAULT); keep context
 130 }
 131
 132 static int do_unescape(const char*s, const char*end, char*n)
 133 {
 134     char*o = n;
 135     int len=0;
 136     while(s<end) {
 137         if(*s!='\\') {
 138             if(o) o[len] = *s;len++;
 139             s++;
 140             continue;
 141         }
 142         s++; //skip past '\'
 143         if(s==end) syntaxerror("invalid \\ at end of string");
 144
 145         /* handle the various line endings (mac, dos, unix) */
 146         if(*s=='\r') {
 147             s++;
 148             if(s==end) break;
 149             if(*s=='\n')
 150                 s++;
 151             continue;
 152         }
 153         if(*s=='\n')  {
 154             s++;
 155             continue;
 156         }
 157         switch(*s) {
 158             case '\\': if(o) o[len] = '\\';s++;len++; break;
 159             case '"': if(o) o[len] = '"';s++;len++; break;
 160             case '\'': if(o) o[len] = '\'';s++;len++; break;
 161             case 'b': if(o) o[len] = '\b';s++;len++; break;
 162             case 'f': if(o) o[len] = '\f';s++;len++; break;
 163             case 'n': if(o) o[len] = '\n';s++;len++; break;
 164             case 'r': if(o) o[len] = '\r';s++;len++; break;
 165             case 't': if(o) o[len] = '\t';s++;len++; break;
 166             case '0': case '1': case '2': case '3': case '4': case '5': case '6': case '7': {
 167                 unsigned int num=0;
 168                 int nr = 0;
 169                 while(strchr("01234567", *s) && nr<3 && s<end) {
 170                     num <<= 3;
 171                     num |= *s-'0';
 172                     nr++;
 173                     s++;
 174                 }
 175                 if(num>256)
 176                     syntaxerror("octal number out of range (0-255): %d", num);
 177                 if(o) o[len] = num;len++;
 178                 continue;
 179             }
 180             case 'x': case 'u': {
 181                 int max=2;
 182                 char bracket = 0;
 183                 char unicode = 0;
 184                 if(*s == 'u') {
 185                     max = 6;
 186                     unicode = 1;
 187                 }
 188                 s++;
 189                 if(s==end) syntaxerror("invalid \\u or \\x at end of string");
 190                 if(*s == '{')  {
 191                     s++;
 192                     if(s==end) syntaxerror("invalid \\u{ at end of string");
 193                     bracket=1;
 194                 }
 195                 unsigned int num=0;
 196                 int nr = 0;
 197                 while(strchr("0123456789abcdefABCDEF", *s) && (bracket || nr < max) && s<end) {
 198                     num <<= 4;
 199                     if(*s>='0' && *s<='9') num |= *s - '0';
 200                     if(*s>='a' && *s<='f') num |= *s - 'a' + 10;
 201                     if(*s>='A' && *s<='F') num |= *s - 'A' + 10;
 202                     nr++;
 203                     s++;
 204                 }
 205                 if(bracket) {
 206                     if(*s=='}' && s<end) {
 207                         s++;
 208                     } else {
 209                         syntaxerror("missing terminating '}'");
 210                     }
 211                 }
 212                 if(unicode) {
 213                     char*utf8 = getUTF8(num);
 214                     while(*utf8) {
 215                         if(o) o[len] = *utf8;utf8++;len++;
 216                     }
 217                 } else {
 218                     if(num>256)
 219                         syntaxerror("byte out of range (0-255): %d", num);
 220                     if(o) o[len] = num;len++;
 221                 }
 222                 break;
 223             }
 224             default: {
 225                 if(o) {
 226                     o[len+0] = '\\';
 227                     o[len+1] = *s;
 228                 }
 229                 s++;
 230                 len+=2;
 231                 break;
 232             }
 233         }
 234     }
 235     if(o) o[len]=0;
 236     return len;
 237 }
 238
 239 static string_t string_unescape(const char*in, int l)
 240 {
 241     const char*s = in;
 242     const char*end = &in[l];
 243
 244     int len = do_unescape(s, end, 0);
 245     char*n = (char*)malloc(len+1);
 246     do_unescape(s, end, n);
 247     string_t out = string_new(n, len);
 248     return out;
 249 }
 250
 251 static void handleCData(char*s, int len)
 252 {
 253     a3_lval.str.str = s+9;    // <![CDATA[
 254     a3_lval.str.len = len-9-3;// ]]>
 255     a3_lval.str.str = strdup_n(a3_lval.str.str, a3_lval.str.len);
 256 }
 257
 258 static void handleRaw(char*s, int len)
 259 {
 260     a3_lval.str.len = len;
 261     a3_lval.str.str = strdup_n(s, a3_lval.str.len);
 262 }
 263
 264 static void handleString(char*s, int len)
 265 {
 266     if(s[0]=='"') {
 267         if(s[len-1]!='"') syntaxerror("String doesn't end with '\"'");
 268         s++;len-=2;
 269     }
 270     else if(s[0]=='\'') {
 271         if(s[len-1]!='\'') syntaxerror("String doesn't end with '\"'");
 272         s++;len-=2;
 273     }
 274     else syntaxerror("String incorrectly terminated");
 275
 276     a3_lval.str = string_unescape(s, len);
 277 }
 278
 279
 280 char start_of_expression;
 281
 282 static inline int m(int type)
 283 {
 284     a3_lval.token = type;
 285     return type;
 286 }
 287
 288 static char numberbuf[64];
 289 static char*nrbuf()
 290 {
 291     if(yyleng>sizeof(numberbuf)-1)
 292         syntaxerror("decimal number overflow");
 293     char*s = numberbuf;
 294     memcpy(s, yytext, yyleng);
 295     s[yyleng]=0;
 296     return s;
 297 }
 298
 299 static inline int setint(int v)
 300 {
 301     a3_lval.number_int = v;
 302     return T_INT;
 303 }
 304 static inline int setfloat(double v)
 305 {
 306     a3_lval.number_float = v;
 307     return T_FLOAT;
 308 }
 309
 310 static inline int handlefloat()
 311 {
 312     char*s = nrbuf();
 313     a3_lval.number_float = atof(s);
 314     return T_FLOAT;
 315 }
 316
 317 static inline int handleint()
 318 {
 319     char*s = nrbuf();
 320     char l = (yytext[0]=='-');
 321
 322     //char*max = l?"1073741824":"2147483647";
 323     char*max = l?"2147483648":"2147483647";
 324
 325     if(yyleng-l>10) {
 326         as3_softwarning("integer overflow: %s (converted to Number)", s);
 327         return handlefloat();
 328     }
 329     if(yyleng-l==10) {
 330         int t;
 331         for(t=0;t<yyleng-l;t++) {
 332             if(yytext[l+t]>max[t]) {
 333                 as3_softwarning("integer overflow: %s (converted to Number)", s);
 334                 return handlefloat();
 335             }
 336             else if(yytext[l+t]<max[t])
 337                 break;
 338         }
 339     }
 340     if(yytext[0]=='-') {
 341         int v = atoi(s);
 342         return setint(v);
 343     } else {
 344         unsigned int v = 0;
 345         int t;
 346         for(t=0;t<yyleng;t++) {
 347             v*=10;
 348             v+=yytext[t]-'0';
 349         }
 350         return setint(v);
 351     }
 352 }
 353
 354 static inline int handlehexfloat()
 355 {
 356     char l = (yytext[0]=='-')+2;
 357     double d=0;
 358     char dot=0;
 359     double base=1;
 360     int t;
 361     for(t=l;t<yyleng;t++) {
 362         char c = yytext[t];
 363         if(c=='.') {
 364             dot=1;
 365             continue;
 366         }
 367         if(!dot) {
 368             d*=16;
 369         } else {
 370             base*=1/16.0;
 371         }
 372         if(c>='0' && c<='9')
 373             d+=(c&15)*base;
 374         else if((c>='a' && c<='f') || (c>='A' && c<='F'))
 375             d+=((c&0x0f)+9)*base;
 376     }
 377     return setfloat(d);
 378 }
 379 static inline int handlehex()
 380 {
 381     char l = (yytext[0]=='-')+2;
 382     int len = yyleng;
 383
 384     if(len-l>8) {
 385         char*s = nrbuf();
 386         syntaxerror("integer overflow %s", s);
 387     }
 388
 389     int t;
 390     unsigned int v = 0;
 391     for(t=l;t<len;t++) {
 392         v<<=4;
 393         char c = yytext[t];
 394         if(c>='0' && c<='9')
 395             v|=(c&15);
 396         else if((c>='a' && c<='f') || (c>='A' && c<='F'))
 397             v|=(c&0x0f)+9;
 398     }
 399     if(l && v>=0x80000000) {
 400         char*s = nrbuf();
 401         as3_softwarning("integer overflow: %s (converted to Number)", s);
 402         return setfloat(v);
 403     }
 404     if(!l && v>0x7fffffff) {
 405         char*s = nrbuf();
 406         as3_softwarning("integer overflow: %s (converted to Number)", s);
 407         return setfloat(v);
 408     }
 409
 410     if(l==3) {
 411         return setint(-(int)v);
 412     } else {
 413         return setint(v);
 414     }
 415 }
 416
 417 void handleLabel(char*text, int len)
 418 {
 419     int t;
 420     for(t=len-1;t>=0;--t) {
 421         if(text[t]!=' ' &&
 422            text[t]!=':')
 423             break;
 424     }
 425     char*s = malloc(t+1);
 426     memcpy(s, yytext, t);
 427     s[t]=0;
 428     a3_lval.id = s;
 429 }
 430
 431 static int handleregexp()
 432 {
 433     char*s = malloc(yyleng);
 434     int len=yyleng-1;
 435     memcpy(s, yytext+1, len);
 436     s[len] = 0;
 437     int t;
 438     for(t=len;t>=0;--t) {
 439         if(s[t]=='/') {
 440             s[t] = 0;
 441             break;
 442         }
 443     }
 444     a3_lval.regexp.pattern = s;
 445     if(t==len) {
 446         a3_lval.regexp.options = 0;
 447     } else {
 448         a3_lval.regexp.options = s+t+1;
 449     }
 450     return T_REGEXP;
 451 }
 452
 453 void initialize_scanner();
 454 #define YY_USER_INIT initialize_scanner();
 455
 456 /* count the number of lines+columns consumed by this token */
 457 static inline void l() {
 458     int t;
 459     for(t=0;t<yyleng;t++) {
 460         if(yytext[t]=='\n') {
 461             current_line++;
 462             current_column=0;
 463         } else {
 464             current_column++;
 465         }
 466     }
 467 }
 468 /* count the number of columns consumed by this token */
 469 static inline void c() {
 470     current_column+=yyleng;
 471 }
 472
 473 trie_t*active_namespaces = 0;
 474 /*void tokenizer_register_namespace(const char*id)
 475 {
 476     trie_put(namespaces, id, 0);
 477 }
 478 void tokenizer_unregister_namespace(const char*id)
 479 {
 480     trie_remove(namespaces, id);
 481 }*/
 482 static inline char tokenizer_is_namespace(const char*id)
 483 {
 484     return trie_contains(active_namespaces, id);
 485 }
 486
 487 static inline int handleIdentifier()
 488 {
 489     char*s = malloc(yyleng+1);
 490     memcpy(s, yytext, yyleng);
 491     s[yyleng]=0;
 492     a3_lval.id = s;
 493     if(tokenizer_is_namespace(s))
 494         return T_NAMESPACE;
 495     else
 496         return T_IDENTIFIER;
 497 }
 498 static int tokenerror();
 499
 500
 501 //Boolean                      {c();return m(KW_BOOLEAN);}
 502 //int                          {c();return m(KW_INT);}
 503 //uint                         {c();return m(KW_UINT);}
 504 //Number                       {c();return m(KW_NUMBER);}
 505 //XMLCOMMENT  <!--([^->]|(-/[^-])|(--/[^>]))*-->
 506
 507 //{XMLCOMMENT}
 508 %}
 509
 510 %s REGEXPOK
 511 %s BEGINNING
 512 %s DEFAULT
 513 %x XMLTEXT
 514 %x XML
 515
 516 NAME     [a-zA-Z_][a-zA-Z0-9_\\]*
 517 _        [^a-zA-Z0-9_\\]
 518
 519 HEXINT    0x[a-zA-Z0-9]+
 520 HEXFLOAT  0x[a-zA-Z0-9]*\.[a-zA-Z0-9]*
 521 INT       [0-9]+
 522 FLOAT     ([0-9]+(\.[0-9]*)?|\.[0-9]+)(e[0-9]+)?
 523
 524 HEXWITHSIGN [+-]?({HEXINT})
 525 HEXFLOATWITHSIGN [+-]?({HEXFLOAT})
 526 INTWITHSIGN [+-]?({INT})
 527 FLOATWITHSIGN [+-]?({FLOAT})
 528
 529 CDATA       <!\[CDATA\[([^]]|\][^]]|\]\][^>])*\]*\]\]\>
 530 XMLCOMMENT  <!--([^->]|[-]+[^>-]|>)*-*-->
 531 XML         <[^>]+{S}>
 532 XMLID       [A-Za-z0-9_\x80-\xff]+([:][A-Za-z0-9_\x80-\xff]+)?
 533 XMLSTRING   ["][^"]*["]
 534
 535 STRING   ["](\\[\x00-\xff]|[^\\"\n])*["]|['](\\[\x00-\xff]|[^\\'\n])*[']
 536 S        [ \n\r\t]
 537 MULTILINE_COMMENT [/][*]+([*][^/]|[^/*]|[^*][/]|[\x00-\x1f])*[*]+[/]
 538 SINGLELINE_COMMENT \/\/[^\n\r]*[\n\r]
 539 REGEXP   [/]([^/\n]|\\[/])*[/][a-zA-Z]*
 540 %%
 541
 542
 543 {SINGLELINE_COMMENT}         {l(); /* single line comment */}
 544 {MULTILINE_COMMENT}          {l(); /* multi line comment */}
 545 [/][*]                       {syntaxerror("syntax error: unterminated comment", yytext);}
 546
 547 ^include{S}+{STRING}{S}*/\n    {l();handleInclude(yytext, yyleng, 1);}
 548 ^include{S}+[^" \t\r\n][\x20-\xff]*{S}*/\n    {l();handleInclude(yytext, yyleng, 0);}
 549 {STRING}                     {l(); BEGIN(DEFAULT);handleString(yytext, yyleng);return T_STRING;}
 550 {CDATA}                      {l(); BEGIN(DEFAULT);handleCData(yytext, yyleng);return T_STRING;}
 551
 552 <DEFAULT,BEGINNING,REGEXPOK>{
 553 {XMLCOMMENT}                 {l(); BEGIN(DEFAULT);handleRaw(yytext, yyleng);return T_STRING;}
 554 }
 555
 556 <XML>{
 557 {XMLSTRING}                  {l(); handleRaw(yytext, yyleng);return T_STRING;}
 558 [{]                          {c(); BEGIN(REGEXPOK);return m('{');}
 559 [<]                          {c(); return m('<');}
 560 [/]                          {c(); return m('/');}
 561 [>]                          {c(); return m('>');}
 562 [=]                          {c(); return m('=');}
 563 {XMLID}                      {c(); handleRaw(yytext, yyleng);return T_IDENTIFIER;}
 564 {S}                          {l();}
 565 <<EOF>>                      {syntaxerror("unexpected end of file");}
 566 }
 567
 568 <XMLTEXT>{
 569 [^<>{]+                      {l(); handleRaw(yytext, yyleng);return T_STRING;}
 570 [{]                          {c(); BEGIN(REGEXPOK);return m('{');}
 571 [<]                          {c(); BEGIN(XML);return m('<');}
 572 [>]                          {c(); return m('>');}
 573 {XMLCOMMENT}                 {l(); handleRaw(yytext, yyleng);return T_STRING;}
 574 {CDATA}                      {l(); handleRaw(yytext, yyleng);return T_STRING;}
 575 <<EOF>>                      {syntaxerror("unexpected end of file");}
 576 }
 577
 578 <BEGINNING,REGEXPOK>{
 579 {REGEXP}                     {c(); BEGIN(DEFAULT);return handleregexp();}
 580 {HEXWITHSIGN}/{_}            {c(); BEGIN(DEFAULT);return handlehex();}
 581 {HEXFLOATWITHSIGN}/{_}       {c(); BEGIN(DEFAULT);return handlehexfloat();}
 582 {INTWITHSIGN}/{_}            {c(); BEGIN(DEFAULT);return handleint();}
 583 {FLOATWITHSIGN}/{_}          {c(); BEGIN(DEFAULT);return handlefloat();}
 584 }
 585
 586 <REGEXPOK>[\{]               {c(); BEGIN(REGEXPOK);return m(T_DICTSTART);}
 587 [\{]                         {c(); BEGIN(DEFAULT); return m('{');}
 588
 589 \xef\xbb\xbf                 {/* utf 8 bom */}
 590 {S}                          {l();}
 591
 592 {HEXINT}/{_}                 {c(); BEGIN(DEFAULT);return handlehex();}
 593 {HEXFLOAT}/{_}               {c(); BEGIN(DEFAULT);return handlehexfloat();}
 594 {INT}/{_}                    {c(); BEGIN(DEFAULT);return handleint();}
 595 {FLOAT}/{_}                  {c(); BEGIN(DEFAULT);return handlefloat();}
 596 NaN                          {c(); BEGIN(DEFAULT);return m(KW_NAN);}
 597
 598 3rr0r                        {/* for debugging: generates a tokenizer-level error */
 599                               syntaxerror("3rr0r");}
 600
 601 {NAME}{S}*:{S}*for/{_}       {l();BEGIN(DEFAULT);handleLabel(yytext, yyleng-3);return T_FOR;}
 602 {NAME}{S}*:{S}*do/{_}        {l();BEGIN(DEFAULT);handleLabel(yytext, yyleng-2);return T_DO;}
 603 {NAME}{S}*:{S}*while/{_}     {l();BEGIN(DEFAULT);handleLabel(yytext, yyleng-5);return T_WHILE;}
 604 {NAME}{S}*:{S}*switch/{_}    {l();BEGIN(DEFAULT);handleLabel(yytext, yyleng-6);return T_SWITCH;}
 605 default{S}xml                {l();BEGIN(DEFAULT);return m(KW_DEFAULT_XML);}
 606 for                          {c();BEGIN(DEFAULT);a3_lval.id="";return T_FOR;}
 607 do                           {c();BEGIN(DEFAULT);a3_lval.id="";return T_DO;}
 608 while                        {c();BEGIN(DEFAULT);a3_lval.id="";return T_WHILE;}
 609 switch                       {c();BEGIN(DEFAULT);a3_lval.id="";return T_SWITCH;}
 610
 611 [&][&]                       {c();BEGIN(REGEXPOK);return m(T_ANDAND);}
 612 [|][|]                       {c();BEGIN(REGEXPOK);return m(T_OROR);}
 613 [!][=]                       {c();BEGIN(REGEXPOK);return m(T_NE);}
 614 [!][=][=]                    {c();BEGIN(REGEXPOK);return m(T_NEE);}
 615 [=][=][=]                    {c();BEGIN(REGEXPOK);return m(T_EQEQEQ);}
 616 [=][=]                       {c();BEGIN(REGEXPOK);return m(T_EQEQ);}
 617 [>][=]                       {c();BEGIN(REGEXPOK);return m(T_GE);}
 618 [<][=]                       {c();BEGIN(REGEXPOK);return m(T_LE);}
 619 [-][-]                       {c();BEGIN(DEFAULT);return m(T_MINUSMINUS);}
 620 [+][+]                       {c();BEGIN(DEFAULT);return m(T_PLUSPLUS);}
 621 [+][=]                       {c();BEGIN(REGEXPOK);return m(T_PLUSBY);}
 622 [\^][=]                      {c();BEGIN(REGEXPOK);return m(T_XORBY);}
 623 [-][=]                       {c();BEGIN(REGEXPOK);return m(T_MINUSBY);}
 624 [/][=]                       {c();BEGIN(REGEXPOK);return m(T_DIVBY);}
 625 [%][=]                       {c();BEGIN(REGEXPOK);return m(T_MODBY);}
 626 [*][=]                       {c();BEGIN(REGEXPOK);return m(T_MULBY);}
 627 [|][=]                       {c();BEGIN(REGEXPOK);return m(T_ORBY);}
 628 [&][=]                       {c();BEGIN(REGEXPOK);return m(T_ANDBY);}
 629 [>][>][=]                    {c();BEGIN(REGEXPOK);return m(T_SHRBY);}
 630 [<][<][=]                    {c();BEGIN(REGEXPOK);return m(T_SHLBY);}
 631 [>][>][>][=]                 {c();BEGIN(REGEXPOK);return m(T_USHRBY);}
 632 [<][<]                       {c();BEGIN(REGEXPOK);return m(T_SHL);}
 633 [>][>][>]                    {c();BEGIN(REGEXPOK);return m(T_USHR);}
 634 [>][>]                       {c();BEGIN(REGEXPOK);return m(T_SHR);}
 635 \.\.\.                       {c();BEGIN(REGEXPOK);return m(T_DOTDOTDOT);}
 636 \.\.                         {c();BEGIN(REGEXPOK);return m(T_DOTDOT);}
 637 \.                           {c();BEGIN(REGEXPOK);return m('.');}
 638 ::                           {c();BEGIN(REGEXPOK);return m(T_COLONCOLON);}
 639 :                            {c();BEGIN(REGEXPOK);return m(':');}
 640 instanceof                   {c();BEGIN(REGEXPOK);return m(KW_INSTANCEOF);}
 641 implements                   {c();BEGIN(REGEXPOK);return m(KW_IMPLEMENTS);}
 642 interface                    {c();BEGIN(DEFAULT);return m(KW_INTERFACE);}
 643 protected                    {c();BEGIN(DEFAULT);return m(KW_PROTECTED);}
 644 namespace                    {c();BEGIN(DEFAULT);return m(KW_NAMESPACE);}
 645 undefined                    {c();BEGIN(DEFAULT);return m(KW_UNDEFINED);}
 646 arguments                    {c();BEGIN(DEFAULT);return m(KW_ARGUMENTS);}
 647 continue                     {c();BEGIN(DEFAULT);return m(KW_CONTINUE);}
 648 override                     {c();BEGIN(DEFAULT);return m(KW_OVERRIDE);}
 649 internal                     {c();BEGIN(DEFAULT);return m(KW_INTERNAL);}
 650 function                     {c();BEGIN(DEFAULT);return m(KW_FUNCTION);}
 651 finally                      {c();BEGIN(DEFAULT);return m(KW_FINALLY);}
 652 default                      {c();BEGIN(DEFAULT);return m(KW_DEFAULT);}
 653 package                      {c();BEGIN(DEFAULT);return m(KW_PACKAGE);}
 654 private                      {c();BEGIN(DEFAULT);return m(KW_PRIVATE);}
 655 dynamic                      {c();BEGIN(DEFAULT);return m(KW_DYNAMIC);}
 656 extends                      {c();BEGIN(DEFAULT);return m(KW_EXTENDS);}
 657 delete                       {c();BEGIN(REGEXPOK);return m(KW_DELETE);}
 658 return                       {c();BEGIN(REGEXPOK);return m(KW_RETURN);}
 659 public                       {c();BEGIN(DEFAULT);return m(KW_PUBLIC);}
 660 native                       {c();BEGIN(DEFAULT);return m(KW_NATIVE);}
 661 static                       {c();BEGIN(DEFAULT);return m(KW_STATIC);}
 662 import                       {c();BEGIN(REGEXPOK);return m(KW_IMPORT);}
 663 typeof                       {c();BEGIN(REGEXPOK);return m(KW_TYPEOF);}
 664 throw                        {c();BEGIN(REGEXPOK);return m(KW_THROW);}
 665 class                        {c();BEGIN(DEFAULT);return m(KW_CLASS);}
 666 const                        {c();BEGIN(DEFAULT);return m(KW_CONST);}
 667 catch                        {c();BEGIN(DEFAULT);return m(KW_CATCH);}
 668 final                        {c();BEGIN(DEFAULT);return m(KW_FINAL);}
 669 false                        {c();BEGIN(DEFAULT);return m(KW_FALSE);}
 670 break                        {c();BEGIN(DEFAULT);return m(KW_BREAK);}
 671 super                        {c();BEGIN(DEFAULT);return m(KW_SUPER);}
 672 each                         {c();BEGIN(DEFAULT);return m(KW_EACH);}
 673 void                         {c();BEGIN(DEFAULT);return m(KW_VOID);}
 674 true                         {c();BEGIN(DEFAULT);return m(KW_TRUE);}
 675 null                         {c();BEGIN(DEFAULT);return m(KW_NULL);}
 676 else                         {c();BEGIN(DEFAULT);return m(KW_ELSE);}
 677 case                         {c();BEGIN(REGEXPOK);return m(KW_CASE);}
 678 with                         {c();BEGIN(REGEXPOK);return m(KW_WITH);}
 679 use                          {c();BEGIN(REGEXPOK);return m(KW_USE);}
 680 new                          {c();BEGIN(REGEXPOK);return m(KW_NEW);}
 681 get                          {c();BEGIN(DEFAULT);return m(KW_GET);}
 682 set                          {c();BEGIN(DEFAULT);return m(KW_SET);}
 683 var                          {c();BEGIN(DEFAULT);return m(KW_VAR);}
 684 try                          {c();BEGIN(DEFAULT);return m(KW_TRY);}
 685 is                           {c();BEGIN(REGEXPOK);return m(KW_IS) ;}
 686 in                           {c();BEGIN(REGEXPOK);return m(KW_IN) ;}
 687 if                           {c();BEGIN(DEFAULT);return m(KW_IF) ;}
 688 as                           {c();BEGIN(REGEXPOK);return m(KW_AS);}
 689 $?{NAME}                       {c();BEGIN(DEFAULT);return handleIdentifier();}
 690
 691 [\]\}*]                       {c();BEGIN(DEFAULT);return m(yytext[0]);}
 692 [+-\/^~@$!%&\(=\[|?:;,<>]   {c();BEGIN(REGEXPOK);return m(yytext[0]);}
 693 [\)\]]                           {c();BEGIN(DEFAULT);return m(yytext[0]);}
 694
 695 <DEFAULT,BEGINNING,REGEXPOK,XML,XMLTEXT>{
 696 .                            {tokenerror();}
 697 }
 698 <<EOF>>                      {l();
 699                               void*b = leave_file();
 700                               if (!b) {
 701                                  yyterminate();
 702                                  yy_delete_buffer(YY_CURRENT_BUFFER);
 703                                  return m(T_EOF);
 704                               } else {
 705                                   yy_delete_buffer(YY_CURRENT_BUFFER);
 706                                   yy_switch_to_buffer(b);
 707                               }
 708                              }
 709
 710 %%
 711
 712 int yywrap()
 713 {
 714     return 1;
 715 }
 716
 717 static int tokenerror()
 718 {
 719     char c1=yytext[0];
 720     char buf[128];
 721     buf[0] = yytext[0];
 722     int t;
 723     for(t=1;t<128;t++) {
 724         char c = buf[t]=input();
 725         if(c=='\n' || c==EOF)  {
 726             buf[t] = 0;
 727             break;
 728         }
 729     }
 730     if(c1>='0' && c1<='9')
 731         syntaxerror("syntax error: %s (identifiers must not start with a digit)");
 732     else
 733         syntaxerror("syntax error [%d]: %s", (yy_start-1)/2, buf);
 734     printf("\n");
 735     exit(1);
 736     yyterminate();
 737 }
 738
 739
 740 static char mbuf[256];
 741 char*token2string(enum yytokentype nr, YYSTYPE v)
 742 {
 743     if(nr==T_STRING) {
 744         char*s = malloc(v.str.len+10);
 745         strcpy(s, "<string>");
 746         memcpy(s+8, v.str.str, v.str.len);
 747         sprintf(s+8+v.str.len, " (%d bytes)", v.str.len);
 748         return s;
 749     }
 750     else if(nr==T_REGEXP) {
 751         char*s = malloc(strlen(v.regexp.pattern)+10);
 752         sprintf(s, "<regexp>%s", v.regexp.pattern);
 753         return s;
 754     }
 755     else if(nr==T_IDENTIFIER) {
 756         char*s = malloc(strlen(v.id)+10);
 757         sprintf(s, "<ID>%s", v.id);
 758         return s;
 759     }
 760     else if(nr==T_INT)     return "<int>";
 761     else if(nr==T_UINT)     return "<uint>";
 762     else if(nr==T_FLOAT)     return "<float>";
 763     else if(nr==T_EOF)        return "***END***";
 764     else if(nr==T_GE)         return ">=";
 765     else if(nr==T_LE)         return "<=";
 766     else if(nr==T_MINUSMINUS) return "--";
 767     else if(nr==T_PLUSPLUS)   return "++";
 768     else if(nr==KW_IMPLEMENTS) return "implements";
 769     else if(nr==KW_INTERFACE)  return "interface";
 770     else if(nr==KW_NAMESPACE)  return "namespace";
 771     else if(nr==KW_PROTECTED)  return "protected";
 772     else if(nr==KW_OVERRIDE)   return "override";
 773     else if(nr==KW_INTERNAL)   return "internal";
 774     else if(nr==KW_FUNCTION)   return "function";
 775     else if(nr==KW_PACKAGE)    return "package";
 776     else if(nr==KW_PRIVATE)    return "private";
 777     else if(nr==KW_BOOLEAN)    return "Boolean";
 778     else if(nr==KW_DYNAMIC)    return "dynamic";
 779     else if(nr==KW_EXTENDS)    return "extends";
 780     else if(nr==KW_PUBLIC)     return "public";
 781     else if(nr==KW_NATIVE)     return "native";
 782     else if(nr==KW_STATIC)     return "static";
 783     else if(nr==KW_IMPORT)     return "import";
 784     else if(nr==KW_NUMBER)     return "number";
 785     else if(nr==KW_CLASS)      return "class";
 786     else if(nr==KW_CONST)      return "const";
 787     else if(nr==KW_FINAL)      return "final";
 788     else if(nr==KW_FALSE)      return "False";
 789     else if(nr==KW_TRUE)       return "True";
 790     else if(nr==KW_UINT)       return "uint";
 791     else if(nr==KW_NULL)       return "null";
 792     else if(nr==KW_ELSE)       return "else";
 793     else if(nr==KW_USE)        return "use";
 794     else if(nr==KW_INT)        return "int";
 795     else if(nr==KW_NEW)        return "new";
 796     else if(nr==KW_GET)        return "get";
 797     else if(nr==KW_SET)        return "set";
 798     else if(nr==KW_VAR)        return "var";
 799     else if(nr==KW_IS)         return "is";
 800     else if(nr==KW_AS)         return "as";
 801     else {
 802         sprintf(mbuf, "%d", nr);
 803         return mbuf;
 804     }
 805 }
 806
 807 void tokenizer_begin_xml()
 808 {
 809     dbg("begin reading xml");
 810     BEGIN(XML);
 811 }
 812 void tokenizer_begin_xmltext()
 813 {
 814     dbg("begin reading xml text");
 815     BEGIN(XMLTEXT);
 816 }
 817 void tokenizer_end_xmltext()
 818 {
 819     dbg("end reading xml text");
 820     BEGIN(XML);
 821 }
 822 void tokenizer_end_xml()
 823 {
 824     dbg("end reading xml");
 825     BEGIN(DEFAULT);
 826 }
 827
 828 void initialize_scanner()
 829 {
 830     BEGIN(BEGINNING);
 831 }
 832
 833