lib/as3/tokenizer.lex

   1 /* tokenizer.lex
   2
   3    Routines for compiling Flash2 AVM2 ABC Actionscript
   4
   5    Extension module for the rfxswf library.
   6    Part of the swftools package.
   7
   8    Copyright (c) 2008 Matthias Kramm <kramm@quiss.org>
   9
  10    This program is free software; you can redistribute it and/or modify
  11    it under the terms of the GNU General Public License as published by
  12    the Free Software Foundation; either version 2 of the License, or
  13    (at your option) any later version.
  14
  15    This program is distributed in the hope that it will be useful,
  16    but WITHOUT ANY WARRANTY; without even the implied warranty of
  17    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18    GNU General Public License for more details.
  19
  20    You should have received a copy of the GNU General Public License
  21    along with this program; if not, write to the Free Software
  22    Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA */
  23 %{
  24
  25
  26 #include <string.h>
  27 #include <stdlib.h>
  28 #include <stdio.h>
  29 #include <stdarg.h>
  30 #include "../utf8.h"
  31 #include "common.h"
  32 #include "tokenizer.h"
  33 #include "files.h"
  34
  35 unsigned int as3_tokencount = 0;
  36
  37 static void dbg(const char*format, ...)
  38 {
  39     char buf[1024];
  40     int l;
  41     va_list arglist;
  42     if(as3_verbosity<3)
  43         return;
  44     va_start(arglist, format);
  45     vsprintf(buf, format, arglist);
  46     va_end(arglist);
  47     l = strlen(buf);
  48     while(l && buf[l-1]=='\n') {
  49         buf[l-1] = 0;
  50         l--;
  51     }
  52     printf("(tokenizer) ");
  53     printf("%s\n", buf);
  54     fflush(stdout);
  55 }
  56
  57 #ifndef YY_CURRENT_BUFFER
  58 #define YY_CURRENT_BUFFER yy_current_buffer
  59 #endif
  60
  61 static void*as3_buffer=0;
  62 static int as3_buffer_pos=0;
  63 static int as3_buffer_len=0;
  64 void as3_file_input(FILE*fi)
  65 {
  66     as3_in = fi;
  67     as3_buffer = 0;
  68 }
  69 void as3_buffer_input(void*buffer, int len)
  70 {
  71     if(!buffer)
  72         syntaxerror("trying to parse zero bytearray");
  73     as3_buffer = buffer;
  74     as3_buffer_len = len;
  75     as3_buffer_pos = 0;
  76     as3_in = 0;
  77 }
  78
  79 #define YY_INPUT(buf,result,max_size) { \
  80   if(!as3_buffer) { \
  81       errno=0; \
  82       while((result = fread(buf, 1, max_size, as3_in))==0 && ferror(as3_in)) \
  83       { if(errno != EINTR) {YY_FATAL_ERROR("input in flex scanner failed"); break;} \
  84         errno=0; clearerr(as3_in); \
  85       } \
  86   } else { \
  87       int to_read = max_size; \
  88       if(to_read + as3_buffer_pos > as3_buffer_len) \
  89           to_read = as3_buffer_len - as3_buffer_pos; \
  90       memcpy(buf, as3_buffer+as3_buffer_pos, to_read); \
  91       as3_buffer_pos += to_read; \
  92       result=to_read; \
  93   } \
  94 }
  95
  96 void handleInclude(char*text, int len, char quotes)
  97 {
  98     char*filename = 0;
  99     if(quotes) {
 100         char*p1 = strchr(text, '"');
 101         char*p2 = strrchr(text, '"');
 102         if(!p1 || !p2 || p1==p2) {
 103             syntaxerror("Invalid include in line %d\n", current_line);
 104         }
 105         *p2 = 0;
 106         filename = strdup(p1+1);
 107     } else {
 108         int i1=0,i2=len;
 109         // find start
 110         while(!strchr(" \n\r\t", text[i1])) i1++;
 111         // strip
 112         while(strchr(" \n\r\t", text[i1])) i1++;
 113         while(strchr(" \n\r\t", text[i2-1])) i2--;
 114         if(i2!=len) text[i2]=0;
 115         filename = strdup(&text[i1]);
 116     }
 117
 118     char*fullfilename = find_file(filename, 1);
 119     enter_file2(filename, fullfilename, YY_CURRENT_BUFFER);
 120     yyin = fopen(fullfilename, "rb");
 121     if (!yyin) {
 122         syntaxerror("Couldn't open include file \"%s\"\n", fullfilename);
 123     }
 124
 125     yy_switch_to_buffer(yy_create_buffer( yyin, YY_BUF_SIZE ) );
 126     //BEGIN(INITIAL); keep context
 127 }
 128
 129 static int do_unescape(const char*s, const char*end, char*n)
 130 {
 131     char*o = n;
 132     int len=0;
 133     while(s<end) {
 134         if(*s!='\\') {
 135             if(o) o[len] = *s;len++;
 136             s++;
 137             continue;
 138         }
 139         s++; //skip past '\'
 140         if(s==end) syntaxerror("invalid \\ at end of string");
 141
 142         /* handle the various line endings (mac, dos, unix) */
 143         if(*s=='\r') {
 144             s++;
 145             if(s==end) break;
 146             if(*s=='\n')
 147                 s++;
 148             continue;
 149         }
 150         if(*s=='\n')  {
 151             s++;
 152             continue;
 153         }
 154         switch(*s) {
 155             case '\\': if(o) o[len] = '\\';s++;len++; break;
 156             case '"': if(o) o[len] = '"';s++;len++; break;
 157             case '\'': if(o) o[len] = '\'';s++;len++; break;
 158             case 'b': if(o) o[len] = '\b';s++;len++; break;
 159             case 'f': if(o) o[len] = '\f';s++;len++; break;
 160             case 'n': if(o) o[len] = '\n';s++;len++; break;
 161             case 'r': if(o) o[len] = '\r';s++;len++; break;
 162             case 't': if(o) o[len] = '\t';s++;len++; break;
 163             case '0': case '1': case '2': case '3': case '4': case '5': case '6': case '7': {
 164                 unsigned int num=0;
 165                 int nr = 0;
 166                 while(strchr("01234567", *s) && nr<3 && s<end) {
 167                     num <<= 3;
 168                     num |= *s-'0';
 169                     nr++;
 170                     s++;
 171                 }
 172                 if(num>256)
 173                     syntaxerror("octal number out of range (0-255): %d", num);
 174                 if(o) o[len] = num;len++;
 175                 continue;
 176             }
 177             case 'x': case 'u': {
 178                 int max=2;
 179                 char bracket = 0;
 180                 char unicode = 0;
 181                 if(*s == 'u') {
 182                     max = 6;
 183                     unicode = 1;
 184                 }
 185                 s++;
 186                 if(s==end) syntaxerror("invalid \\u or \\x at end of string");
 187                 if(*s == '{')  {
 188                     s++;
 189                     if(s==end) syntaxerror("invalid \\u{ at end of string");
 190                     bracket=1;
 191                 }
 192                 unsigned int num=0;
 193                 int nr = 0;
 194                 while(strchr("0123456789abcdefABCDEF", *s) && (bracket || nr < max) && s<end) {
 195                     num <<= 4;
 196                     if(*s>='0' && *s<='9') num |= *s - '0';
 197                     if(*s>='a' && *s<='f') num |= *s - 'a' + 10;
 198                     if(*s>='A' && *s<='F') num |= *s - 'A' + 10;
 199                     nr++;
 200                     s++;
 201                 }
 202                 if(bracket) {
 203                     if(*s=='}' && s<end) {
 204                         s++;
 205                     } else {
 206                         syntaxerror("missing terminating '}'");
 207                     }
 208                 }
 209                 if(unicode) {
 210                     char*utf8 = getUTF8(num);
 211                     while(*utf8) {
 212                         if(o) o[len] = *utf8;utf8++;len++;
 213                     }
 214                 } else {
 215                     if(num>256)
 216                         syntaxerror("byte out of range (0-255): %d", num);
 217                     if(o) o[len] = num;len++;
 218                 }
 219                 break;
 220             }
 221             default: {
 222                 if(o) {
 223                     o[len+0] = '\\';
 224                     o[len+1] = *s;
 225                 }
 226                 s++;
 227                 len+=2;
 228                 break;
 229             }
 230         }
 231     }
 232     if(o) o[len]=0;
 233     return len;
 234 }
 235
 236 static string_t string_unescape(const char*in, int l)
 237 {
 238     const char*s = in;
 239     const char*end = &in[l];
 240
 241     int len = do_unescape(s, end, 0);
 242     char*n = (char*)malloc(len+1);
 243     do_unescape(s, end, n);
 244     string_t out = string_new(n, len);
 245     return out;
 246 }
 247
 248 static void handleCData(char*s, int len)
 249 {
 250     a3_lval.str.str = s+9;    // <![CDATA[
 251     a3_lval.str.len = len-9-3;// ]]>
 252     a3_lval.str.str = strdup_n(a3_lval.str.str, a3_lval.str.len);
 253 }
 254
 255 static void handleString(char*s, int len)
 256 {
 257     if(s[0]=='"') {
 258         if(s[len-1]!='"') syntaxerror("String doesn't end with '\"'");
 259         s++;len-=2;
 260     }
 261     else if(s[0]=='\'') {
 262         if(s[len-1]!='\'') syntaxerror("String doesn't end with '\"'");
 263         s++;len-=2;
 264     }
 265     else syntaxerror("String incorrectly terminated");
 266
 267     a3_lval.str = string_unescape(s, len);
 268 }
 269
 270
 271 char start_of_expression;
 272
 273 static inline int m(int type)
 274 {
 275     a3_lval.token = type;
 276     return type;
 277 }
 278
 279
 280 static char numberbuf[64];
 281 static char*nrbuf()
 282 {
 283     if(yyleng>sizeof(numberbuf)-1)
 284         syntaxerror("decimal number overflow");
 285     char*s = numberbuf;
 286     memcpy(s, yytext, yyleng);
 287     s[yyleng]=0;
 288     return s;
 289 }
 290
 291 static inline int setint(int v)
 292 {
 293     a3_lval.number_int = v;
 294     return T_INT;
 295 }
 296 static inline int setfloat(double v)
 297 {
 298     a3_lval.number_float = v;
 299     return T_FLOAT;
 300 }
 301
 302 static inline int handlefloat()
 303 {
 304     char*s = nrbuf();
 305     a3_lval.number_float = atof(s);
 306     return T_FLOAT;
 307 }
 308
 309 static inline int handleint()
 310 {
 311     char*s = nrbuf();
 312     char l = (yytext[0]=='-');
 313
 314     //char*max = l?"1073741824":"2147483647";
 315     char*max = l?"2147483648":"2147483647";
 316
 317     if(yyleng-l>10) {
 318         as3_softwarning("integer overflow: %s (converted to Number)", s);
 319         return handlefloat();
 320     }
 321     if(yyleng-l==10) {
 322         int t;
 323         for(t=0;t<yyleng-l;t++) {
 324             if(yytext[l+t]>max[t]) {
 325                 as3_softwarning("integer overflow: %s (converted to Number)", s);
 326                 return handlefloat();
 327             }
 328             else if(yytext[l+t]<max[t])
 329                 break;
 330         }
 331     }
 332     if(yytext[0]=='-') {
 333         int v = atoi(s);
 334         return setint(v);
 335     } else {
 336         unsigned int v = 0;
 337         int t;
 338         for(t=0;t<yyleng;t++) {
 339             v*=10;
 340             v+=yytext[t]-'0';
 341         }
 342         return setint(v);
 343     }
 344 }
 345
 346 static inline int handlehexfloat()
 347 {
 348     char l = (yytext[0]=='-')+2;
 349     double d=0;
 350     char dot=0;
 351     double base=1;
 352     int t;
 353     for(t=l;t<yyleng;t++) {
 354         char c = yytext[t];
 355         if(c=='.') {
 356             dot=1;
 357             continue;
 358         }
 359         if(!dot) {
 360             d*=16;
 361         } else {
 362             base*=1/16.0;
 363         }
 364         if(c>='0' && c<='9')
 365             d+=(c&15)*base;
 366         else if((c>='a' && c<='f') || (c>='A' && c<='F'))
 367             d+=((c&0x0f)+9)*base;
 368     }
 369     return setfloat(d);
 370 }
 371 static inline int handlehex()
 372 {
 373     char l = (yytext[0]=='-')+2;
 374     int len = yyleng;
 375
 376     if(len-l>8) {
 377         char*s = nrbuf();
 378         syntaxerror("integer overflow %s", s);
 379     }
 380
 381     int t;
 382     unsigned int v = 0;
 383     for(t=l;t<len;t++) {
 384         v<<=4;
 385         char c = yytext[t];
 386         if(c>='0' && c<='9')
 387             v|=(c&15);
 388         else if((c>='a' && c<='f') || (c>='A' && c<='F'))
 389             v|=(c&0x0f)+9;
 390     }
 391     if(l && v>=0x80000000) {
 392         char*s = nrbuf();
 393         as3_softwarning("integer overflow: %s (converted to Number)", s);
 394         return setfloat(v);
 395     }
 396     if(!l && v>0x7fffffff) {
 397         char*s = nrbuf();
 398         as3_softwarning("integer overflow: %s (converted to Number)", s);
 399         return setfloat(v);
 400     }
 401
 402     if(l==3) {
 403         return setint(-(int)v);
 404     } else {
 405         return setint(v);
 406     }
 407 }
 408
 409 void handleLabel(char*text, int len)
 410 {
 411     int t;
 412     for(t=len-1;t>=0;--t) {
 413         if(text[t]!=' ' &&
 414            text[t]!=':')
 415             break;
 416     }
 417     char*s = malloc(t+1);
 418     memcpy(s, yytext, t);
 419     s[t]=0;
 420     a3_lval.id = s;
 421 }
 422
 423 static int handleregexp()
 424 {
 425     char*s = malloc(yyleng);
 426     int len=yyleng-1;
 427     memcpy(s, yytext+1, len);
 428     s[len] = 0;
 429     int t;
 430     for(t=len;t>=0;--t) {
 431         if(s[t]=='/') {
 432             s[t] = 0;
 433             break;
 434         }
 435     }
 436     a3_lval.regexp.pattern = s;
 437     if(t==len) {
 438         a3_lval.regexp.options = 0;
 439     } else {
 440         a3_lval.regexp.options = s+t+1;
 441     }
 442     return T_REGEXP;
 443 }
 444
 445 void initialize_scanner();
 446 #define YY_USER_INIT initialize_scanner();
 447
 448 /* count the number of lines+columns consumed by this token */
 449 static inline void l() {
 450     int t;
 451     for(t=0;t<yyleng;t++) {
 452         if(yytext[t]=='\n') {
 453             current_line++;
 454             current_column=0;
 455         } else {
 456             current_column++;
 457         }
 458     }
 459 }
 460 /* count the number of columns consumed by this token */
 461 static inline void c() {
 462     current_column+=yyleng;
 463 }
 464
 465 trie_t*active_namespaces = 0;
 466 /*void tokenizer_register_namespace(const char*id)
 467 {
 468     trie_put(namespaces, id, 0);
 469 }
 470 void tokenizer_unregister_namespace(const char*id)
 471 {
 472     trie_remove(namespaces, id);
 473 }*/
 474 static inline tokenizer_is_namespace(const char*id)
 475 {
 476     return trie_contains(active_namespaces, id);
 477 }
 478
 479 static inline int handleIdentifier()
 480 {
 481     char*s = malloc(yyleng+1);
 482     memcpy(s, yytext, yyleng);
 483     s[yyleng]=0;
 484     a3_lval.id = s;
 485     if(tokenizer_is_namespace(s))
 486         return T_NAMESPACE;
 487     else
 488         return T_IDENTIFIER;
 489 }
 490
 491
 492 //Boolean                      {c();return m(KW_BOOLEAN);}
 493 //int                          {c();return m(KW_INT);}
 494 //uint                         {c();return m(KW_UINT);}
 495 //Number                       {c();return m(KW_NUMBER);}
 496
 497 %}
 498
 499 %s REGEXPOK
 500 %s BEGINNING
 501
 502 NAME     [a-zA-Z_][a-zA-Z0-9_\\]*
 503 _        [^a-zA-Z0-9_\\]
 504
 505 HEXINT    0x[a-zA-Z0-9]+
 506 HEXFLOAT  0x[a-zA-Z0-9]*\.[a-zA-Z0-9]*
 507 INT       [0-9]+
 508 FLOAT     ([0-9]+(\.[0-9]*)?|\.[0-9]+)(e[0-9]+)?
 509
 510 HEXWITHSIGN [+-]?({HEXINT})
 511 HEXFLOATWITHSIGN [+-]?({HEXFLOAT})
 512 INTWITHSIGN [+-]?({INT})
 513 FLOATWITHSIGN [+-]?({FLOAT})
 514
 515 CDATA    <!\[CDATA\[([^]]|\][^]]|\]\][^>])*\]*\]\]\>
 516 STRING   ["](\\[\x00-\xff]|[^\\"\n])*["]|['](\\[\x00-\xff]|[^\\'\n])*[']
 517 S        [ \n\r\t]
 518 MULTILINE_COMMENT [/][*]+([*][^/]|[^/*]|[^*][/]|[\x00-\x1f])*[*]+[/]
 519 SINGLELINE_COMMENT \/\/[^\n\r]*[\n\r]
 520 REGEXP   [/]([^/\n]|\\[/])*[/][a-zA-Z]*
 521 %%
 522
 523
 524 {SINGLELINE_COMMENT}         {l(); /* single line comment */}
 525 {MULTILINE_COMMENT}          {l(); /* multi line comment */}
 526 [/][*]                       {syntaxerror("syntax error: unterminated comment", yytext);}
 527
 528 ^include{S}+{STRING}{S}*/\n    {l();handleInclude(yytext, yyleng, 1);}
 529 ^include{S}+[^" \t\r\n][\x20-\xff]*{S}*/\n    {l();handleInclude(yytext, yyleng, 0);}
 530 {STRING}                     {l(); BEGIN(INITIAL);handleString(yytext, yyleng);return T_STRING;}
 531 {CDATA}                      {l(); BEGIN(INITIAL);handleCData(yytext, yyleng);return T_STRING;}
 532
 533 <BEGINNING,REGEXPOK>{
 534 {REGEXP}                     {c(); BEGIN(INITIAL);return handleregexp();}
 535 {HEXWITHSIGN}/{_}            {c(); BEGIN(INITIAL);return handlehex();}
 536 {HEXFLOATWITHSIGN}/{_}       {c(); BEGIN(INITIAL);return handlehexfloat();}
 537 {INTWITHSIGN}/{_}            {c(); BEGIN(INITIAL);return handleint();}
 538 {FLOATWITHSIGN}/{_}          {c(); BEGIN(INITIAL);return handlefloat();}
 539 }
 540
 541 <REGEXPOK>[\{]               {c(); BEGIN(REGEXPOK);return m(T_DICTSTART);}
 542 [\{]                         {c(); BEGIN(INITIAL); return m('{');}
 543
 544 \xef\xbb\xbf                 {/* utf 8 bom */}
 545 {S}                          {l();}
 546
 547 {HEXINT}/{_}                 {c(); BEGIN(INITIAL);return handlehex();}
 548 {HEXFLOAT}/{_}               {c(); BEGIN(INITIAL);return handlehexfloat();}
 549 {INT}/{_}                    {c(); BEGIN(INITIAL);return handleint();}
 550 {FLOAT}/{_}                  {c(); BEGIN(INITIAL);return handlefloat();}
 551 NaN                          {c(); BEGIN(INITIAL);return m(KW_NAN);}
 552
 553 3rr0r                        {/* for debugging: generates a tokenizer-level error */
 554                               syntaxerror("3rr0r");}
 555
 556 {NAME}{S}*:{S}*for/{_}       {l();BEGIN(INITIAL);handleLabel(yytext, yyleng-3);return T_FOR;}
 557 {NAME}{S}*:{S}*do/{_}        {l();BEGIN(INITIAL);handleLabel(yytext, yyleng-2);return T_DO;}
 558 {NAME}{S}*:{S}*while/{_}     {l();BEGIN(INITIAL);handleLabel(yytext, yyleng-5);return T_WHILE;}
 559 {NAME}{S}*:{S}*switch/{_}    {l();BEGIN(INITIAL);handleLabel(yytext, yyleng-6);return T_SWITCH;}
 560 for                          {c();BEGIN(INITIAL);a3_lval.id="";return T_FOR;}
 561 do                           {c();BEGIN(INITIAL);a3_lval.id="";return T_DO;}
 562 while                        {c();BEGIN(INITIAL);a3_lval.id="";return T_WHILE;}
 563 switch                       {c();BEGIN(INITIAL);a3_lval.id="";return T_SWITCH;}
 564
 565 [&][&]                       {c();BEGIN(REGEXPOK);return m(T_ANDAND);}
 566 [|][|]                       {c();BEGIN(REGEXPOK);return m(T_OROR);}
 567 [!][=]                       {c();BEGIN(REGEXPOK);return m(T_NE);}
 568 [!][=][=]                    {c();BEGIN(REGEXPOK);return m(T_NEE);}
 569 [=][=][=]                    {c();BEGIN(REGEXPOK);return m(T_EQEQEQ);}
 570 [=][=]                       {c();BEGIN(REGEXPOK);return m(T_EQEQ);}
 571 [>][=]                       {c();BEGIN(REGEXPOK);return m(T_GE);}
 572 [<][=]                       {c();BEGIN(REGEXPOK);return m(T_LE);}
 573 [-][-]                       {c();BEGIN(INITIAL);return m(T_MINUSMINUS);}
 574 [+][+]                       {c();BEGIN(INITIAL);return m(T_PLUSPLUS);}
 575 [+][=]                       {c();BEGIN(REGEXPOK);return m(T_PLUSBY);}
 576 [\^][=]                      {c();BEGIN(REGEXPOK);return m(T_XORBY);}
 577 [-][=]                       {c();BEGIN(REGEXPOK);return m(T_MINUSBY);}
 578 [/][=]                       {c();BEGIN(REGEXPOK);return m(T_DIVBY);}
 579 [%][=]                       {c();BEGIN(REGEXPOK);return m(T_MODBY);}
 580 [*][=]                       {c();BEGIN(REGEXPOK);return m(T_MULBY);}
 581 [|][=]                       {c();BEGIN(REGEXPOK);return m(T_ORBY);}
 582 [>][>][=]                    {c();BEGIN(REGEXPOK);return m(T_SHRBY);}
 583 [<][<][=]                    {c();BEGIN(REGEXPOK);return m(T_SHLBY);}
 584 [>][>][>][=]                 {c();BEGIN(REGEXPOK);return m(T_USHRBY);}
 585 [<][<]                       {c();BEGIN(REGEXPOK);return m(T_SHL);}
 586 [>][>][>]                    {c();BEGIN(REGEXPOK);return m(T_USHR);}
 587 [>][>]                       {c();BEGIN(REGEXPOK);return m(T_SHR);}
 588 \.\.\.                       {c();BEGIN(REGEXPOK);return m(T_DOTDOTDOT);}
 589 \.\.                         {c();BEGIN(REGEXPOK);return m(T_DOTDOT);}
 590 \.                           {c();BEGIN(REGEXPOK);return m('.');}
 591 ::                           {c();BEGIN(REGEXPOK);return m(T_COLONCOLON);}
 592 :                            {c();BEGIN(REGEXPOK);return m(':');}
 593 instanceof                   {c();BEGIN(REGEXPOK);return m(KW_INSTANCEOF);}
 594 implements                   {c();BEGIN(REGEXPOK);return m(KW_IMPLEMENTS);}
 595 interface                    {c();BEGIN(INITIAL);return m(KW_INTERFACE);}
 596 namespace                    {c();BEGIN(INITIAL);return m(KW_NAMESPACE);}
 597 protected                    {c();BEGIN(INITIAL);return m(KW_PROTECTED);}
 598 undefined                    {c();BEGIN(INITIAL);return m(KW_UNDEFINED);}
 599 continue                     {c();BEGIN(INITIAL);return m(KW_CONTINUE);}
 600 override                     {c();BEGIN(INITIAL);return m(KW_OVERRIDE);}
 601 internal                     {c();BEGIN(INITIAL);return m(KW_INTERNAL);}
 602 function                     {c();BEGIN(INITIAL);return m(KW_FUNCTION);}
 603 finally                      {c();BEGIN(INITIAL);return m(KW_FINALLY);}
 604 default                      {c();BEGIN(INITIAL);return m(KW_DEFAULT);}
 605 package                      {c();BEGIN(INITIAL);return m(KW_PACKAGE);}
 606 private                      {c();BEGIN(INITIAL);return m(KW_PRIVATE);}
 607 dynamic                      {c();BEGIN(INITIAL);return m(KW_DYNAMIC);}
 608 extends                      {c();BEGIN(INITIAL);return m(KW_EXTENDS);}
 609 delete                       {c();BEGIN(REGEXPOK);return m(KW_DELETE);}
 610 return                       {c();BEGIN(REGEXPOK);return m(KW_RETURN);}
 611 public                       {c();BEGIN(INITIAL);return m(KW_PUBLIC);}
 612 native                       {c();BEGIN(INITIAL);return m(KW_NATIVE);}
 613 static                       {c();BEGIN(INITIAL);return m(KW_STATIC);}
 614 import                       {c();BEGIN(REGEXPOK);return m(KW_IMPORT);}
 615 typeof                       {c();BEGIN(REGEXPOK);return m(KW_TYPEOF);}
 616 throw                        {c();BEGIN(REGEXPOK);return m(KW_THROW);}
 617 class                        {c();BEGIN(INITIAL);return m(KW_CLASS);}
 618 const                        {c();BEGIN(INITIAL);return m(KW_CONST);}
 619 catch                        {c();BEGIN(INITIAL);return m(KW_CATCH);}
 620 final                        {c();BEGIN(INITIAL);return m(KW_FINAL);}
 621 false                        {c();BEGIN(INITIAL);return m(KW_FALSE);}
 622 break                        {c();BEGIN(INITIAL);return m(KW_BREAK);}
 623 super                        {c();BEGIN(INITIAL);return m(KW_SUPER);}
 624 each                         {c();BEGIN(INITIAL);return m(KW_EACH);}
 625 void                         {c();BEGIN(INITIAL);return m(KW_VOID);}
 626 true                         {c();BEGIN(INITIAL);return m(KW_TRUE);}
 627 null                         {c();BEGIN(INITIAL);return m(KW_NULL);}
 628 else                         {c();BEGIN(INITIAL);return m(KW_ELSE);}
 629 case                         {c();BEGIN(REGEXPOK);return m(KW_CASE);}
 630 with                         {c();BEGIN(REGEXPOK);return m(KW_WITH);}
 631 use                          {c();BEGIN(REGEXPOK);return m(KW_USE);}
 632 new                          {c();BEGIN(REGEXPOK);return m(KW_NEW);}
 633 get                          {c();BEGIN(INITIAL);return m(KW_GET);}
 634 set                          {c();BEGIN(INITIAL);return m(KW_SET);}
 635 var                          {c();BEGIN(INITIAL);return m(KW_VAR);}
 636 try                          {c();BEGIN(INITIAL);return m(KW_TRY);}
 637 is                           {c();BEGIN(REGEXPOK);return m(KW_IS) ;}
 638 in                           {c();BEGIN(REGEXPOK);return m(KW_IN) ;}
 639 if                           {c();BEGIN(INITIAL);return m(KW_IF) ;}
 640 as                           {c();BEGIN(REGEXPOK);return m(KW_AS);}
 641 $?{NAME}                       {c();BEGIN(INITIAL);return handleIdentifier();}
 642
 643 [\]\}*]                       {c();BEGIN(INITIAL);return m(yytext[0]);}
 644 [+-\/^~@$!%&\(=\[|?:;,<>]   {c();BEGIN(REGEXPOK);return m(yytext[0]);}
 645 [\)\]]                           {c();BEGIN(INITIAL);return m(yytext[0]);}
 646
 647 .                            {/* ERROR */
 648                               char c1=yytext[0];
 649                               char buf[128];
 650                               buf[0] = yytext[0];
 651                               int t;
 652                               for(t=1;t<128;t++) {
 653                                   char c = buf[t]=input();
 654                                   if(c=='\n' || c==EOF)  {
 655                                       buf[t] = 0;
 656                                       break;
 657                                   }
 658                               }
 659                               if(c1>='0' && c1<='9')
 660                                   syntaxerror("syntax error: %s (identifiers must not start with a digit)");
 661                               else
 662                                   syntaxerror("syntax error: %s", buf);
 663                               printf("\n");
 664                               exit(1);
 665                               yyterminate();
 666                              }
 667 <<EOF>>                      {l();
 668                               void*b = leave_file();
 669                               if (!b) {
 670                                  yyterminate();
 671                                  yy_delete_buffer(YY_CURRENT_BUFFER);
 672                                  return m(T_EOF);
 673                               } else {
 674                                   yy_delete_buffer(YY_CURRENT_BUFFER);
 675                                   yy_switch_to_buffer(b);
 676                               }
 677                              }
 678
 679 %%
 680
 681 int yywrap()
 682 {
 683     return 1;
 684 }
 685
 686 static char mbuf[256];
 687 char*token2string(enum yytokentype nr, YYSTYPE v)
 688 {
 689     if(nr==T_STRING) {
 690         char*s = malloc(v.str.len+10);
 691         strcpy(s, "<string>");
 692         memcpy(s+8, v.str.str, v.str.len);
 693         sprintf(s+8+v.str.len, " (%d bytes)", v.str.len);
 694         return s;
 695     }
 696     else if(nr==T_REGEXP) {
 697         char*s = malloc(strlen(v.regexp.pattern)+10);
 698         sprintf(s, "<regexp>%s", v.regexp.pattern);
 699         return s;
 700     }
 701     else if(nr==T_IDENTIFIER) {
 702         char*s = malloc(strlen(v.id)+10);
 703         sprintf(s, "<ID>%s", v.id);
 704         return s;
 705     }
 706     else if(nr==T_INT)     return "<int>";
 707     else if(nr==T_UINT)     return "<uint>";
 708     else if(nr==T_FLOAT)     return "<float>";
 709     else if(nr==T_EOF)        return "***END***";
 710     else if(nr==T_GE)         return ">=";
 711     else if(nr==T_LE)         return "<=";
 712     else if(nr==T_MINUSMINUS) return "--";
 713     else if(nr==T_PLUSPLUS)   return "++";
 714     else if(nr==KW_IMPLEMENTS) return "implements";
 715     else if(nr==KW_INTERFACE)  return "interface";
 716     else if(nr==KW_NAMESPACE)  return "namespace";
 717     else if(nr==KW_PROTECTED)  return "protected";
 718     else if(nr==KW_OVERRIDE)   return "override";
 719     else if(nr==KW_INTERNAL)   return "internal";
 720     else if(nr==KW_FUNCTION)   return "function";
 721     else if(nr==KW_PACKAGE)    return "package";
 722     else if(nr==KW_PRIVATE)    return "private";
 723     else if(nr==KW_BOOLEAN)    return "Boolean";
 724     else if(nr==KW_DYNAMIC)    return "dynamic";
 725     else if(nr==KW_EXTENDS)    return "extends";
 726     else if(nr==KW_PUBLIC)     return "public";
 727     else if(nr==KW_NATIVE)     return "native";
 728     else if(nr==KW_STATIC)     return "static";
 729     else if(nr==KW_IMPORT)     return "import";
 730     else if(nr==KW_NUMBER)     return "number";
 731     else if(nr==KW_CLASS)      return "class";
 732     else if(nr==KW_CONST)      return "const";
 733     else if(nr==KW_FINAL)      return "final";
 734     else if(nr==KW_FALSE)      return "False";
 735     else if(nr==KW_TRUE)       return "True";
 736     else if(nr==KW_UINT)       return "uint";
 737     else if(nr==KW_NULL)       return "null";
 738     else if(nr==KW_ELSE)       return "else";
 739     else if(nr==KW_USE)        return "use";
 740     else if(nr==KW_INT)        return "int";
 741     else if(nr==KW_NEW)        return "new";
 742     else if(nr==KW_GET)        return "get";
 743     else if(nr==KW_SET)        return "set";
 744     else if(nr==KW_VAR)        return "var";
 745     else if(nr==KW_IS)         return "is";
 746     else if(nr==KW_AS)         return "as";
 747     else {
 748         sprintf(mbuf, "%d", nr);
 749         return mbuf;
 750     }
 751 }
 752
 753 void initialize_scanner()
 754 {
 755     BEGIN(BEGINNING);
 756 }
 757
 758